example-spa-elm-app/flake.nix

{
  inputs = {
    nixpkgs = {
      url = "github:NixOS/nixpkgs/nixpkgs-unstable";
    };
    utils.url = "github:numtide/flake-utils";
    mkElmDerivation.url = "github:jeslie0/mkElmDerivation";
    flake-compat = {
      url = "github:edolstra/flake-compat";
      flake = false;
    };
  };

  outputs =
    inputs:
    inputs.utils.lib.eachDefaultSystem (
      system:
      let
        pkgs = import inputs.nixpkgs {
          localSystem = system;
          overlays = [
            inputs.mkElmDerivation.overlays.default
            (final: prev: {
              example-spa-elm-app = prev.callPackage (
                {
                  stdenv,
                  lib,
                  elmPackages,
                  uglify-js,
                  rustPlatform,
                  cargo,
                  rustc,
                }:
                stdenv.mkDerivation (
                  let
                    allPackagesJsonPath = "${inputs.mkElmDerivation}/mkElmDerivation/all-packages.json";
                    elmHashesJsonPath = "${inputs.mkElmDerivation}/mkElmDerivation/elm-hashes.json";
                    snapshot = import "${inputs.mkElmDerivation}/src/snapshot/default.nix" (
                      prev.haskellPackages // { inherit lib; }
                    );
                    elmJson = ./frontend/elm.json;
                  in
                  {
                    pname = "example-spa-elm-app";
                    version = "0.1.0";
                    src = inputs.self;

                    nativeBuildInputs = [
                      elmPackages.elm
                      uglify-js
                      rustPlatform.cargoSetupHook
                      cargo
                      rustc
                    ];

                    cargoDeps = pkgs.rustPlatform.importCargoLock {
                      lockFile = ./backend/Cargo.lock;
                      allowBuiltinFetchGit = true;
                    };

                    cargoRoot = "backend";

                    makeFlags = [
                      "RELEASE=1"
                      "frontend"
                      "backend"
                    ];

                    postPatch = ''
                      patchShebangs ./frontend/build.sh
                    '';

                    preBuild = ''
                      (
                        cd frontend
                        ${
                          (import "${inputs.mkElmDerivation}/nix/lib.nix" {
                            inherit
                              stdenv
                              lib
                              snapshot
                              allPackagesJsonPath
                              ;
                          }).mkDotElmCommand
                          elmHashesJsonPath
                          elmJson
                        }
                      )
                      export ELM_HOME=$PWD/frontend/.elm
                    '';

                    installPhase = ''
                      runHook preInstall
                      mkdir -p $out
                      cp -r ./public $out/
                      cp ./backend/target/debug/backend $out/
                      runHook postInstall
                    '';
                  }
                )
              ) { };
            })
          ];
        };
      in
      {
        packages = {
          default = inputs.self.packages."${system}".example-spa-elm-app;
          example-spa-elm-app = pkgs.example-spa-elm-app;
        };

        devShells.default =
          with pkgs;
          mkShell {
            inputsFrom = [ example-spa-elm-app ];
            buildInputs = [
              nodejs_22
             ];

             shellHook = ''
               if [ ! -d "$PWD/frontend/node_modules/elm-go" ]; then
                 echo "Installing elm-go..."
                 cd "$PWD/frontend"
                 ${nodejs_22}/bin/npm install elm-go
                 cd ..
               fi
               export PATH="$PWD/frontend/node_modules/.bin:$PATH"
             '';
          };
      }
    );
}